@echo off
setlocal
chcp 65001 >nul
title manchaDIGITAL - Asistencia remota
color 1F
echo.
echo  ==============================================
echo       manchaDIGITAL - ASISTENCIA REMOTA
echo  ==============================================
echo.
echo  Este programa iniciara una sesion de soporte.
echo  Usted podra cerrar RustDesk en cualquier momento.
echo.
set /p CODE=Introduzca su codigo de asistencia de 6 cifras: 
echo %CODE%| findstr /r "^[0-9][0-9][0-9][0-9][0-9][0-9]$" >nul || (echo Codigo no valido.& pause & exit /b 1)
set "DIR=%TEMP%\manchaDIGITAL-Soporte"
if not exist "%DIR%" mkdir "%DIR%"
set "EXE=%DIR%\rustdesk.exe"
if not exist "%EXE%" (
  echo.
  echo Descargando el componente seguro de control remoto...
  powershell -NoProfile -ExecutionPolicy Bypass -Command "try { Invoke-WebRequest -UseBasicParsing 'https://github.com/rustdesk/rustdesk/releases/download/1.4.9/rustdesk-1.4.9-x86_64.exe' -OutFile '%EXE%' } catch { exit 1 }"
  if errorlevel 1 (echo No se pudo descargar el componente.& pause & exit /b 1)
)
start "" "%EXE%"
echo Esperando a que el programa quede preparado...
timeout /t 8 /nobreak >nul
for /f "usebackq delims=" %%I in (`"%EXE%" --get-id 2^>nul`) do if not defined RID set "RID=%%I"
if not defined RID (echo No se pudo obtener el ID remoto. Deje RustDesk abierto y facilite el ID al tecnico.& pause & exit /b 1)
for /f "delims=" %%H in ('hostname') do set "PC=%%H"
powershell -NoProfile -ExecutionPolicy Bypass -Command "$b=@{code='%CODE%';remote_id='%RID%';computer='%PC%'}|ConvertTo-Json; try { Invoke-RestMethod -Method Post -Uri 'https://manchadigital.com/support/agent.php' -ContentType 'application/json' -Body $b | Out-Null; exit 0 } catch { exit 1 }"
echo.
echo  Equipo preparado. ID remoto: %RID%
echo  Mantenga RustDesk abierto y facilite al tecnico la
echo  contrasena de un solo uso que aparece en su ventana.
echo.
echo  Para finalizar la asistencia, cierre RustDesk.
echo.
pause
